parse_escape_sequence_with_argument Subroutine

   pure subroutine parse_escape_sequence_with_argument(ca, ierr)
      use :: forgex_segment_m
      use :: forgex_parameters_m
      use :: forgex_utf8_m
      use :: forgex_error_m
      implicit none
      type(character_array_t), intent(inout), allocatable :: ca(:)
      integer, intent(inout) :: ierr

      type(character_array_t), allocatable :: tmp(:)
      character(2) :: hex_two_digit
      character(:), allocatable :: hex_long
      integer :: i, j, k, siz, ib, ie

      ierr = SYNTAX_VALID
      if (.not. allocated(ca)) then
         ierr = ALLOCATION_ERR
         return
      end if


      hex_two_digit = ''
      hex_long = ''

      siz = size(ca, dim=1)
      allocate(tmp(siz))

      k = 1
      j = 1
      outer: do while (j <= siz)
         if (ca(j)%c == ESCAPE_X .and. ca(j)%is_escaped) then
            tmp(k)%c = ESCAPE_X
            tmp(k)%is_escaped = .true.
            j = j + 1
            if (j > siz) exit outer
            k = k + 1

            if (j+1 <= siz) then

               if ((ichar_utf8(ca(j)%c) .in. SEG_HEX) .and. (ichar_utf8(ca(j+1)%c) .in. SEG_HEX) )then
                  hex_two_digit = trim(ca(j)%c)//trim(ca(j+1)%c)
                  tmp(k)%c = trim(adjustl(hex_two_digit))
                  ! tmp(k)%is_escaped = .true.
                  tmp(k)%is_hyphenated = ca(j+1)%is_hyphenated
                  j = j + 2
                  if (j > siz) exit outer
                  k = k + 1
                  cycle
   
               else if (ca(j)%c == SYMBOL_LCRB) then
                  i = j + 1
                  reader: do while (.true.)

                     if (i > siz) then
                        ierr = SYNTAX_ERR_CURLYBRACE_MISSING
                        return
                     end if

                     if (ca(i)%c /= SYMBOL_RCRB .and. .not. (ichar_utf8(ca(i)%c) .in. SEG_HEX)) then
                        ierr = SYNTAX_ERR_INVALID_HEXADECIMAL
                        return
                     else if (ca(i)%c == SYMBOL_RCRB) then
                        exit reader
                     end if
                     hex_long = trim(adjustl(hex_long))//ca(i)%c
                     i = i + 1
                  end do reader

                  tmp(k)%c = trim(adjustl(hex_long))
                  ! tmp(k)%is_escaped = .true.
                  tmp(k)%is_hyphenated = ca(i)%is_hyphenated

                  j = i + 1
                  if (j > siz) exit outer
                  k = k + 1
                  
                  hex_long = ''
                  cycle
               else
                  ierr = SYNTAX_ERR_INVALID_HEXADECIMAL
                  return
               end if

            else
               ierr = SYNTAX_ERR_HEX_DIGITS_NOT_ENOUGH
               return
            end if

         else if (ca(j)%c == ESCAPE_P) then
            ierr = SYNTAX_ERR_UNICODE_PROPERTY_NOT_IMPLEMENTED
            return
         end if

         tmp(k) = ca(j)
         
         j = j + 1
         if (j > siz) exit
         k = k + 1
      end do outer

      deallocate(ca)
      allocate(ca(k))
      ca(:) = tmp(1:k)

      ! call dump_character_array_t_list(tmp)
      ! call dump_character_array_t_list(ca)
      
   end subroutine parse_escape_sequence_with_argument