tree_graph__hexadecimal_to_codepoint Subroutine

   pure subroutine tree_graph__hexadecimal_to_codepoint(self, cp)
      implicit none
      class(tree_t), intent(inout) :: self
      integer(int32), intent(inout) :: cp

      character(:), allocatable :: buf, fmt
      character(6) :: hex_c
      character(8) :: hex_len_c
      integer :: i, ios
      logical :: is_two_digit, is_longer_digit

      buf = ''

      call self%tape%get_token()

      is_longer_digit = self%tape%current_token == tk_lcurlybrace
      is_two_digit = .not. is_longer_digit

      if (is_longer_digit) call self%tape%get_token()

      buf = self%tape%token_char(1:1) ! First, get the second digit.
      i = 2

      reader: do while(.true.)
         if (is_two_digit .and. i >= 3) exit reader
         call self%tape%get_token()

         if (is_longer_digit .and. self%tape%current_token /= tk_rcurlybrace .and. self%tape%current_token /= tk_char) then
            self%is_valid = .false.
            self%code = SYNTAX_ERR_CURLYBRACE_MISSING
            return
         end if

         if (self%tape%current_token == tk_rcurlybrace) exit reader
         buf = buf//self%tape%token_char(1:1)
         i = i + 1
      end do reader

      hex_c = trim(adjustl(buf))

      write(hex_len_c, '(i0)', iostat=ios) len_trim(hex_c)
      if (ios /= 0) then
         self%code = SYNTAX_ERR_INVALID_HEXADECIMAL
         return
      endif

      fmt = '(z'//trim(hex_len_c)//')'
      read(hex_c, fmt=fmt, iostat=ios) cp

      if (ios /= 0) then
         self%code = SYNTAX_ERR_INVALID_HEXADECIMAL
         return
      end if

      if (.not. (cp .in. SEG_WHOLE)) then
         self%code = SYNTAX_ERR_UNICODE_EXCEED
         return
      end if

   end subroutine tree_graph__hexadecimal_to_codepoint